Gambas ONE

Code: Select all

' Gambas class file

' Load the pigpio library
Library "/usr/local/lib/libpigpio"

' Set up the calls
Public Extern gpioInitialise() As Integer   'call at start of program to initialise 
Public Extern gpioTerminate() As Integer    'call at end of program to release resources and terminate threads
Public Extern gpioVersion() As Integer
Public Extern gpioHardwareRevision() As Integer
Public Extern gpioSetMode(iPin As Integer, iMode As Integer) As Integer
Public Extern gpioRead(iPin As Integer) As Integer
Public Extern gpioWrite(iPin As Integer, iLevel As Integer) As Integer
Public Extern gpioSetPullUpDown(iPin As Integer, iMode As Integer) As Integer
Public Extern gpioServo(servo_pin As Integer, servo_value As Integer) As Integer

' Define constants
Const PI_INPUT As Integer = 0
Const PI_OUTPUT As Integer = 1
Const PI_PUD_UP As Integer = 2
Const PI_PUD_DOWN As Integer = 1
Const PI_PUD_OFF As Integer = 0

' Public Variables

Public Sub Form_Open()
  Dim intReply As Integer
  intReply = gpioInitialise()
  Dim sw1_pin As Integer
  sw1_pin = 26
  gpioSetMode(sw1_pin, PI_INPUT)
  gpioSetPullUpDown(sw1_pin, PI_PUD_UP)
  
  If intReply < 0 Then
    Label1.Text = "Failed: must be run as root"
    BTN_LED_16.Enabled = False
  Else
    BTN_LED_16.Enabled = True
    Label1.Text = "Initialised: pigpio version no: " & intReply
    Me.Text = "Pi hardware rev: " & Hex$(gpioHardwareRevision())
    Me.Text &= ",  pigpio vers: " & gpioVersion()
    Me.Tag = 0
  Endif
 
servoslider.value = 1500
GAUGE.Picture = Picture.Load("/home/pi/G2-IMAGE/G2-0050.png")

End

Public Sub Form_Close()
   gpioTerminate()
End

Public Sub BTN_LED_16_Click()
  Dim LED_Pin As Integer 
  LED_Pin = 16
  Dim LED_STATUS As Integer

  gpioSetMode(LED_Pin, PI_OUTPUT)
  LED_STATUS = gpioRead(LED_Pin)
  
  If LED_STATUS = 0 Then
    LED_STAT_DSP.Text = "LED 16 ON"
    gpioWrite(LED_Pin, 1)
    BTN_LED_16.Background = &H00ff00
  Else
    LED_STAT_DSP.Text = "LED 16 OFF"
    gpioWrite(LED_Pin, 0)  
    BTN_LED_16.Background = &Hff0000
    
  Endif
End

Public Sub Timer1_Timer()
Dim s1_value As Integer
Dim sw1_pin As Integer

sw1_pin = 26
s1_value = gpioRead(sw1_pin)
If s1_value = 0 Then
  SW1_STATUS.Text = "PRESSED"
Else
  SW1_STATUS.Text = "IDLE"
Endif

End

Public Sub servoslider_Change()
Dim pic_name As String
Dim pic_number As Variant
Dim mydata As String

slide_dsp.Text = servoslider.Value
gpioServo(17, servoslider.Value)
pic_number = servoslider.Value - 599
pic_number = pic_number * (100 / 1801)
If pic_number < 1 Then pic_number = 1
TextBox2.Text = Int(pic_number)
pic_name = "/home/pi/G2-IMAGE/G2-" & Format(pic_number, "0000") & ".png"

GAUGE.Picture = Picture.Load(pic_name)

End



Public Sub btn_servo_center_Click()
  servoslider.value = 1500
End

Public Sub btn_servo_left_Click()
  servoslider.value = 600
End

Public Sub btn_servo_right_Click()
  servoslider.value = 2400
End