find a control

[bill-lancaster]

I have a number of frames on a form which are generated dynamically, to recover information about a specific frame I do this:

Code: Select all

Dim hCtrl As Control
  For Each hCtrl In Me.Controls
    If hCtrl.Name = Last.Name Then
		do things!
    Endif
  Next

Having set the frame's .Name to a unique value.

Is there a better way to do this?

[thatbruce]

Hard to tell without the context in which this code is executed, but maybe

  Dim hCtl as Object
  hCtl = Last
  DoThings

[bill-lancaster]

OK, with this code:-

Code: Select all

Public Sub Form_Open()
Dim hFrame As Frame
Dim i As Integer
  For i = 0 To 4
    With hFrame = New Frame(Me)
      .Name = "A" & i
      .X = (i * 60)
      .Y = 50
      .W = 50
      .H = 50
      .Text = "B" & i
    End With
  Next
End

How best can I find the .text value of one of the frames?

At the moment I'm using:-

Code: Select all

Dim hCtrl As Control
  For Each hCtrl In Me.Controls
    If hCtrl.Name = "A2" Then
	Print hCtrl.Text
    Endif
  Next

[bill-lancaster]

Sorry, correction. This is my current method:-

Code: Select all

Public Sub Button1_Click()
Dim hCtrl As Control
Dim hFrm As Frame
  For Each hCtrl In Me.Controls
    If hCtrl.Name = "A2" Then
      hFrm = hCtrl
      Print hFrm.Text
    Endif
  Next
End

[vuott]

You can avoid two lines from your code:

Public Sub Button1_Click()

  Dim ob as Object
  
  For Each ob In Me.Controls
    If ob.Name = "A2" Then Print ob.Text
  Next
  
End

[thatbruce]

Ah, yes. Obviously Last wont work, as Last is the button.
But, if you know the name of the control, e.g. "A2" then doesn't Me.A2 work?
or maybe Me.Controls["A2"]
I'm just poking about here.
b

[bill-lancaster]

Thanks Vuott, this works and is much better than my original

Dim hFrm As Frame
hFrm = Me.Controls["A3"]
Print hFrm.Text

Thanks for your advice.

[vuott]

Thanks Vuott, this works...

Actually, my code is more functional if you have Controls of various types on the Form that do not need to be searched based on one of their Properties.
If, on the other hand, you need to know the text, owned by the ".Text" Property of a specific Control, to which a value has also been assigned to the ".Name" Property, I think thatbruce's suggestion is better.

[BruceSteers]

Should also be able to just use the form array

Me["A3"]
or
Form1["A3"]

Dim hFrm As Frame = Me["A3"]
Print hFrm.Text

[vuott]

...you could also use an array of Frame:

Private ffrr As New Frame[5]

Public Sub Form_Open()

  For b As Byte = 0 To 4
    With ffrr[b] = New Frame(Me)
      .Name = "A" & b
      .X = (b * 60)
      .Y = 50
      .W = 50
      .H = 50
      .Text = "B" & b
    End With
  Next

End

Public Sub Button1_Click()

  Print ffrr[2].Text

End