Gambas ONE

Dim sTargetFile As String = User.Home &/ "new-file.txt"
If not Exist(sTargetFile) Then Copy "./Templates/MyTemplate.txt" To sTargetFile

Dim aResults As String[]

aResults = ListTextFiles(User.Home)

Public Sub ListTextFiles(Path As String) As String[]

 Return Dir(Path, "*.txt", gb.file)

End

Dim aResults As String[]
aResults = ListTextMimeFiles(User.Home)

Public Sub ListTextMimeFiles(Path As String) As String[]

  Dim aTextFiles As New String[]

  Dim aFiles As String[] = Dir(Path, "*", gb.File)

  For Each sFile As String In aFiles
    If DesktopMime.FromFile(Path &/ sFile).Type = "text/plain" Then aTextFiles.Add(sFile)
   Next

  Return aTextFiles

End

GridViewList As GridView
TextAreaEdit As TextArea
sFiles As String[]
sLang As String[]

Public Sub Form_Open()
  
  Setup
  GetFiles
  
End

Public Sub GetFiles()
  
  Dim iRow As Integer 
  
  sFiles = RDir(User.Home, "*.txt", gb.File).Sort()
  
  For iRow = 0 To sFiles.Max
    If sFiles[iRow] Begins "." Then Continue ''Don't show hidden files (No mostrar archivos ocultos)
    Inc GridViewList.Rows.Count
    GridViewList[GridViewList.Rows.Max, 0].Text = User.Home &/ sFiles[iRow]
  Next
  
  Me.Title = sLang[0] & "(" & Str(GridViewList.Rows.Count) & ")"
  
End

Public Sub GridViewList_Click()
  
  Dim iLast As Integer = Last.Row
  Dim iRow, iColour As Integer 
  Dim bBold As Boolean
  
  For iRow = 0 To GridViewList.Rows.Max
    iColour = Color.Default 
    bBold = False
    If iRow = iLast Then 
      iColour = Color.LightGray
      bBold = True
    End If
    GridViewList[iRow, 0].Background = iColour
    GridViewList[iRow, 0].Font.Bold = bBold
  Next
  
End

Public Sub GridViewList_DblClick()
  
  GridViewList.Visible = False
  TextAreaEdit.Visible = True
  
  TextAreaEdit.Text = File.Load(GridViewList[Last.Row, 0].Text)
  Me.Title = GridViewList[Last.Row, 0].Text
  
End

Public Sub Setup()
  
  If System.Language Begins "en" Then sLang = ["Text file list", "Double click to open"]
  If System.Language Begins "es" Then sLang = ["Lista de archivos de texto", "Doble clic para abrir"]
  
  With Me
    .Arrangement = Arrange.Vertical
    .Padding = 5
    .Height = 550
    .Width = 850
  End With
  
  With GridViewList = New GridView(Me) As "GridViewList"
    .Columns.Count = 1
    .Rows.Count = 0
    .ScrollBar = GridView.Vertical
    .Grid = False
    .Expand = True
    .Header = GridView.Vertical
    .Tooltip = sLang[1]
    .Visible = True
  End With
  
  With TextAreaEdit = New TextArea(Me)
    .Expand = True
    .Wrap = True
    .Visible = False
  End With
  
End